'**********************************************
' vbs Cache类
' 属性valid,是否可用,取值前判断
' 属性name,cache名,新建对象后赋值
' 方法add(值,到期时间),设置cache内容
' 属性value,返回cache内容
' 属性blempty,是否未设置值
' 方法makeEmpty,释放内存,测试用
' 方法equal(变量1),判断cache值是否和变量1相同
' 方法expires(time),修改过期时间为time
'**********************************************
class Cache
private obj 'cache内容
private expireTime '过期时间
private expireTimeName '过期时间application名
private cacheName 'cache内容application名
private path 'uri
private sub class_initialize()
path=request.servervariables("url")
path=left(path,instrRev(path,"/"))
end sub
private sub class_terminate()
end sub
public property get blEmpty
'是否为空
if isempty(obj) then
blEmpty=true
else
blEmpty=false
end if
end property
public property get valid
'是否可用(过期)
if isempty(obj) or not isDate(expireTime) then
valid=false
elseif CDate(expireTime)<now then
valid=false
else
valid=true
end if
end property
public property let name(str)
'设置cache名
cacheName=str & path
obj=application(cacheName)
expireTimeName=str & "expires" & path
expireTime=application(expireTimeName)
end property
public property let expires(tm)
'重设置过期时间
expireTime=tm
application.lock
application(expireTimeName)=expireTime
application.unlock
end property
public sub add(var,expire)
'赋值
if isempty(var) or not isDate(expire) then
exit sub
end if
obj=var
expireTime=expire
application.lock
application(cacheName)=obj
application(expireTimeName)=expireTime
application.unlock
end sub
public property get value
'取值
if isempty(obj) or not isDate(expireTime) then
value=null
elseif CDate(expireTime)<now then
value=null
else
value=obj
end if
end property
public sub makeEmpty()
'释放application
application.lock
application(cacheName)=empty
application(expireTimeName)=empty
application.unlock
obj=empty
expireTime=empty
end sub
public function equal(var2)
'比较
if typename(obj)<>typename(var2) then
equal=false
elseif typename(obj)="Object" then
if obj is var2 then
equal=true
else
equal=false
end if
elseif typename(obj)="Variant()" then
if join(obj,"^")=join(var2,"^") then
equal=true
else
equal=false
end if
else
if obj=var2 then
equal=true
else
equal=false
end if
end if
end function
end class
使用:
set myCache=New Cache
myCache.name="blog_user"
if myCache.valid then
blog_user=split(myCache.value,"|")
for i=1 to ubound(blog_user)
response.write blog_user(i)&"<br>"
next
else
set rs=conn.execute("SELECT blog_user FROM blog_reg ORDER BY blog_id DESC")
while not rs.eof
xxx=xxx&"|"&rs("blog_user")
rs.movenext:wend:rs.close:set rs=nothing
BoardJumpList=xxx
myCache.add BoardJumpList,dateadd("n",60,now)
response.write BoardJumpList
end if
分享到:
相关推荐
【asp】缓存类提高处理速度
'为防止同服务器缓存混淆,设置专用名称 Dim APP_FRIST_CHAR:APP_FRIST_CHAR="_MOO_CN_APP_" '---------------------------- class appCache '---------------------------- private keySch_ '索引缓存键值名 ...
超级缓存技术缓存技术asp页面缓存缓存技术asp页面缓存
asp.net缓存技术 详解 让你快速掌握asp.net缓存技术
ASP.NET 缓存:方法和最佳实践,讲解如何在ASP.NET下使用缓存技术
作为.Net框架下开发Web应用程序的主打产品,ASP.NET充分考虑了缓存机制。通过某种方法,将系统需要的数据对象、Web页面存储在内存中,使得Web站点在需要获取这些数据时,不需要经过繁琐的数据库连接、查询和复杂的...
asp.net页面缓存:片断缓存,数据缓存
ASP.NET_缓存技术 ASP.NET_缓存技术
里面主要包含asp.net常用的两种缓存技术一是页面输出缓存,二是应用程序缓存,有相应的例子两个以上和对应的说明文档
asp.net2.0缓存文档 PDF格式
ASP.NET2010 数据库缓存 很简单的一个例子
ASP用建立缓存,存放数据。ASP用建立缓存存取数据。
本人编写的Asp超级缓存类,之所以叫超级,是因为本缓存类不同于普通的缓存类。 本类使用HTTP协议中的缓存标志来控制缓存。若合理使用,则极大的减轻服务器带宽及CPU压力。有效的提升每秒处理页数。
作为.Net框架下开发Web应用程序的主打产品,ASP.NET充分考虑了缓存机制。通过某种方法,将系统需要的数据对象、Web页面存储在内存中,使得Web站点在需要获取这些数据时,不需要经过繁琐的数据库连接、查询和复杂的...
Asp.net 缓存技术总结,如何提高页面访问速度,如何快速打开大数据量页面?
自己整理的.net缓存资料及类型 何时用到缓存 缓存的利与弊等等
充分利用ASP.NET的三种缓存提高站点性能.docx 充分利用ASP.NET的三种缓存提高站点性能.docx
描述了ASP.NET现有的各种缓存技术实现,附有示例代码。
asp.net页面缓存技术(Cache、XML) 概述ASP.NET缓存机制